@ECHO OFF

rem 27-MAY-97    H-01-32    IVK    $$1	Initial submission to PDM40.
rem 15-MAR-99    I-01-32    Cherie $$2	SPR753898: change shutmode
REM 22-JUN-99    I-01-37    APB    $$3  Add set and check ORACLE_SID
rem 14-Oct-99    I-2.0.0.12 APB    $$4  Bug fix #778008
REM 20-Jan-00    I4.0.0.21  APB    $$5  Dleted DOS style line-ends

if "%PROI_HOME%"=="" set PROI_HOME=%ORACLE_HOME%

if not "%1"=="" set ORACLE_SID=%1

if "%ORACLE_SID%"=="" goto SID_MESS

set PDM_STARTUP_FILE=%PROI_HOME%\database\ilink_utils\dbshut.sql

echo connect sysop/sysop as sysoper;                >  %PDM_STARTUP_FILE%
echo shutdown immediate;                            >> %PDM_STARTUP_FILE%
echo exit                                           >> %PDM_STARTUP_FILE%

echo Connect as sysoper...
%ORACLE_HOME%\bin\svrmgr23 command=@%PDM_STARTUP_FILE% | find /I "01031" || goto POST_SHUTDOWN

if "%INTERNAL_PASSWD%" == "" set INTERNAL_PASSWD=internal
echo Connect as internal...
echo connect internal/%INTERNAL_PASSWD% as sysoper; >  %PDM_STARTUP_FILE%
echo shutdown immediate;                            >> %PDM_STARTUP_FILE%
echo exit                                           >> %PDM_STARTUP_FILE%

%ORACLE_HOME%\bin\svrmgr23 command=@%PDM_STARTUP_FILE% | find /I "ORACLE instance shut down" || goto BAD_MESSAGE

:POST_SHUTDOWN
net start | find /I "OracleStart%ORACLE_SID%" || goto OTHER_SERV
net stop OracleStart%ORACLE_SID%
:OTHER_SERV
net stop OracleService%ORACLE_SID%
net stop OracleTNSListener
goto TO_EXIT

:BAD_MESSAGE
echo Database %ORACLE_SID% not shutted down.
echo Set variable INTERNAL_PASSWD (password for internal)
echo and try again.
goto TO_EXIT

:SID_MESS
echo Environment variable ORACLE_SID is not set.
echo You should set this variable before run this
echo script or run it with parameter <ORACLE_SID>

:TO_EXIT
if exist %PDM_STARTUP_FILE% del /f /q %PDM_STARTUP_FILE%