@ECHO OFF
REM 18-JAN-99    I-01-14    APB    $$1      Initial submission. Add recover database.
REM 22-JUN-99    I-01-37    APB    $$2      Add set and check ORACLE_SID
REM 01-SEP-99    I-02-07    APB    $$3      Delete "lsnrctl start" because listener started automatically

if "%PROI_HOME%"=="" set PROI_HOME=%ORACLE_HOME%

if not "%1"=="" set ORACLE_SID=%1

if "%ORACLE_SID%"=="" goto SID_MESS

net start | find /I "OracleTNSListener" || net start OracleTNSListener
net start | find /I "OracleService%ORACLE_SID%" || net start OracleService%ORACLE_SID%

%ORACLE_HOME%\bin\svrmgr23 command=@%PROI_HOME%\database\ilink_utils\dbstart_ilink.sql
%ORACLE_HOME%\bin\svrmgr23 command=@%PROI_HOME%\database\ilink_utils\dbstart_test.sql | find /I "PUBLIC" || goto RECOVER

goto END

:RECOVER
if "%INTERNAL_PASSWD%" == "" set INTERNAL_PASSWD=internal
set PDM_RECOVER_FILE=%PROI_HOME%\database\ilink_utils\dbstart_recov.sql

echo connect internal/%INTERNAL_PASSWD% ;   >  %PDM_RECOVER_FILE%
echo startup mount;                         >> %PDM_RECOVER_FILE%
echo recover database;                      >> %PDM_RECOVER_FILE%
echo alter database open;                   >> %PDM_RECOVER_FILE%
echo grant sysoper to sysop;                >> %PDM_RECOVER_FILE%
echo exit                                   >> %PDM_RECOVER_FILE%

%ORACLE_HOME%\bin\svrmgr23 command=@%PDM_RECOVER_FILE%

if exist %PDM_RECOVER_FILE% del /f /q %PDM_RECOVER_FILE%

%ORACLE_HOME%\bin\svrmgr23 command=@%PROI_HOME%\database\ilink_utils\dbstart_test.sql | find /I "PUBLIC" || goto BAD_MESS

goto END

:SID_MESS
echo Environment variable ORACLE_SID is not set.
echo You should set this variable before run this
echo script or run it with parameter <ORACLE_SID>
goto TO_EXIT

:BAD_MESS
echo Database %ORACLE_SID% not started.
echo Set variable INTERNAL_PASSWD (password for internal)
echo and try again.
goto TO_EXIT

:END

echo Database %ORACLE_SID% started.
@ECHO ON

:TO_EXIT